it-swarm.com.de

Verwenden von Excel VBA zum Ausführen einer SQL-Abfrage

Ich bin ziemlich neu in SQL und VBA. Ich habe eine SQL-Abfrage geschrieben, die ich aus einem VBA-Unter in einer Excel-Arbeitsmappe aufrufen und ausführen und dann die Abfrageergebnisse in die Arbeitsmappe übernehmen möchte. Ich habe einige Subs online gefunden (Stackoverflow und andere Stellen), die behaupten, dies zu tun, aber ich habe Probleme, sie zu verstehen, da sie keine Erklärung enthalten. Zum Beispiel ist hier ein Sub, das ich online gefunden habe:

Sub ConnectSqlServer()

    Dim conn As ADODB.Connection
    Dim rs As ADODB.Recordset
    Dim sConnString As String

    ' Create the connection string.
    sConnString = "Provider=SQLOLEDB;Data Source=INSTANCE\SQLEXPRESS;" & _
                  "Initial Catalog=MyDatabaseName;" & _
                  "Integrated Security=SSPI;"

    ' Create the Connection and Recordset objects.
    Set conn = New ADODB.Connection
    Set rs = New ADODB.Recordset

    ' Open the connection and execute.
    conn.Open sConnString
    Set rs = conn.Execute("SELECT * FROM Table1;")

    ' Check we have data.
    If Not rs.EOF Then
        ' Transfer result.
        Sheets(1).Range("A1").CopyFromRecordset rs
    ' Close the recordset
        rs.Close
    Else
        MsgBox "Error: No records returned.", vbCritical
    End If

    ' Clean up
    If CBool(conn.State And adStateOpen) Then conn.Close
    Set conn = Nothing
    Set rs = Nothing

End Sub

Zuallererst würde das funktionieren? Zweitens, was muss ich im Sub ersetzen (es sieht nach Anbieter, Datenquelle, erstem Katalog usw. aus) und wo finde ich die Informationen, durch die ich sie ersetzen kann?

Ich hoffe, dass diese Frage nicht zu verwirrend ist und bedanke mich für Ihre Hilfe!

38
Sam

Unten ist Code, den ich zurzeit verwende, um Daten von einem MS SQL Server 2008 in VBA zu ziehen. Sie müssen sicherstellen, dass Sie über die richtige ADODB-Referenz verfügen [VBA-Editor-> Tools-> Verweise] und dass Sie über eine Microsoft ActiveX Data Objects 2.8-Bibliothek verfügen checked, das ist die zweite Zeile aus der unteren Zeile, die aktiviert ist (ich verwende Excel 2010 unter Windows 7; möglicherweise haben Sie eine etwas andere ActiveX-Version, diese beginnt jedoch immer noch mit Microsoft ActiveX):

References required for SQL

Submodul für die Verbindung zu MS SQL mit Remote Host & Benutzername/Passwort

Sub Download_Standard_BOM()
'Initializes variables
Dim cnn As New ADODB.Connection
Dim rst As New ADODB.Recordset
Dim ConnectionString As String
Dim StrQuery As String

'Setup the connection string for accessing MS SQL database
   'Make sure to change:
       '1: PASSWORD
       '2: USERNAME
       '3: REMOTE_IP_ADDRESS
       '4: DATABASE
    ConnectionString = "Provider=SQLOLEDB.1;Password=PASSWORD;Persist Security Info=True;User ID=USERNAME;Data Source=REMOTE_IP_ADDRESS;Use Procedure for Prepare=1;Auto Translate=True;Packet Size=4096;Use Encryption for Data=False;Tag with column collation when possible=False;Initial Catalog=DATABASE"

    'Opens connection to the database
    cnn.Open ConnectionString
    'Timeout error in seconds for executing the entire query; this will run for 15 minutes before VBA timesout, but your database might timeout before this value
    cnn.CommandTimeout = 900

    'This is your actual MS SQL query that you need to run; you should check this query first using a more robust SQL editor (such as HeidiSQL) to ensure your query is valid
    StrQuery = "SELECT TOP 10 * FROM tbl_table"

    'Performs the actual query
    rst.Open StrQuery, cnn
    'Dumps all the results from the StrQuery into cell A2 of the first sheet in the active workbook
    Sheets(1).Range("A2").CopyFromRecordset rst
End Sub
44
Michael