it-swarm.com.de

Google Spreadsheet - mehrere IF-Anweisungen zwischen Nummernbereichen

Ich versuche, eine Formel mit mehreren IF-Anweisungen zwischen Zahlenbereichen einzurichten, aber ich erhalte den Fehler "Formelanalysefehler". 

Hier ist das Forum:

=IF((AND(A2>0,A2<500),"Less than 500",
 If(AND(A2>=500,A2<1000),"Between 500 and 1000"),
 If(AND(A2>=1000,A2<1500),"Between 1000 and 1500"),
 If(AND(A2>=1500,A2<2000),"Between 1500 and 2000")))
14
Kristin

Wegen der verschachtelten IFs ist es etwas knifflig, aber hier ist meine Antwort (in Google Spreadsheets bestätigt):

=IF(AND(A2>=0,    A2<500),  "Less than 500", 
 IF(AND(A2>=500,  A2<1000), "Between 500 and 1000", 
 IF(AND(A2>=1000, A2<1500), "Between 1000 and 1500", 
 IF(AND(A2>=1500, A2<2000), "Between 1500 and 2000", "Undefined"))))
30
eniacAvenger

Ich schlage vor, die Funktion vlookup zu verwenden, um die nächste Übereinstimmung zu erhalten.


Schritt 1

Bereiten Sie den Datenbereich vor und benennen Sie ihn: 'numberRange':

 enter image description here

Wählen Sie den Bereich aus. Gehen Sie zum Menü: Daten → Benannte Bereiche ... → Definieren Sie den neuen benannten Bereich.

Schritt 2

Verwenden Sie diese einfache Formel:

=VLOOKUP(A2,numberRange,2)

 enter image description here


Auf diese Weise können Sie Fehler auslassen und das Ergebnis leicht korrigieren.

8
Max Makhrov

Standalone-One-Cell-Lösung basierend auf VLOOKUP

US-Syntax:

=IFERROR(ARRAYFORMULA(IF(LEN(A2:A),
        IF(A2:A>2000, "More than 2000",VLOOKUP(A2:A,
 {{(TRANSPOSE({{{0;   "Less than 500"},
               {500;  "Between 500 and 1000"}},
              {{1000; "Between 1000 and 1500"},
               {1500; "Between 1500 and 2000"}}}))}}, 2)),)), )

EU-Syntax:

=IFERROR(ARRAYFORMULA(IF(LEN(A2:A);
        IF(A2:A>2000; "More than 2000";VLOOKUP(A2:A;
 {{(TRANSPOSE({{{0;   "Less than 500"}\
               {500;  "Between 500 and 1000"}}\
              {{1000; "Between 1000 and 1500"}\
               {1500; "Between 1500 and 2000"}}}))}}; 2));)); )

alternativen: https://webapps.stackexchange.com/questions/123729/

0
player0

Kürzer als angenommen A, leicht erweiterbar und Adressen 0 und darunter:

=if(or(A2<=0,A2>2000),"?",if(A2<500,"Less than 500","Between "&500*int(A2/500)&" and "&500*(int(A2/500)+1))) 
0
pnuts