it-swarm.com.de

Oracle PL / SQL - Wie erstelle ich eine einfache Array-Variable?

Ich möchte eine speicherinterne Array-Variable erstellen, die in meinem PL/SQL-Code verwendet werden kann. Ich kann in Oracle PL/SQL keine Sammlungen finden, die reinen Speicher verwenden. Sie scheinen alle mit Tabellen verknüpft zu sein. In meinem PL/SQL-Code (C # -Syntax) möchte ich Folgendes tun:

string[] arrayvalues = new string[3] {"Matt", "Joanne", "Robert"};

Edit: Oracle: 9i

119
contactmatt

Sie können VARRAY für ein Array mit fester Größe verwenden:

declare
   type array_t is varray(3) of varchar2(10);
   array array_t := array_t('Matt', 'Joanne', 'Robert');
begin
   for i in 1..array.count loop
       dbms_output.put_line(array(i));
   end loop;
end;

Oder TABELLE für ein unbegrenztes Array:

...
   type array_t is table of varchar2(10);
...

Das Wort "Tabelle" hat hier verwirrenderweise nichts mit Datenbanktabellen zu tun. Beide Methoden erstellen speicherinterne Arrays.

In beiden Fällen müssen Sie die Sammlung initialisieren und erweitern, bevor Sie Elemente hinzufügen:

declare
   type array_t is varray(3) of varchar2(10);
   array array_t := array_t(); -- Initialise it
begin
   for i in 1..3 loop
      array.extend(); -- Extend it
      array(i) := 'x';
   end loop;
end;

Der erste Index ist 1 nicht 0.

226
Tony Andrews

Sie könnten einfach DBMS_SQL.VARCHAR2_TABLE deklarieren, um ein In-Memory-Array variabler Länge aufzunehmen, das von einem BINARY_INTEGER indiziert wird:

DECLARE
   name_array dbms_sql.varchar2_table;
BEGIN
   name_array(1) := 'Tim';
   name_array(2) := 'Daisy';
   name_array(3) := 'Mike';
   name_array(4) := 'Marsha';
   --
   FOR i IN name_array.FIRST .. name_array.LAST
   LOOP
      -- Do something
   END LOOP;
END;

Sie können ein assoziatives Array (früher als PL/SQL-Tabellen bezeichnet) verwenden, da es sich um ein speicherinternes Array handelt.

DECLARE
   TYPE employee_arraytype IS TABLE OF employee%ROWTYPE
        INDEX BY PLS_INTEGER;
   employee_array employee_arraytype;
BEGIN
   SELECT *
     BULK COLLECT INTO employee_array
     FROM employee
    WHERE department = 10;
   --
   FOR i IN employee_array.FIRST .. employee_array.LAST
   LOOP
      -- Do something
   END LOOP;
END;

Das assoziative Array kann beliebige Datensatztypen enthalten.

Hoffe es hilft, Ollie.

58
Ollie

Sie können auch ein Oracle defined collection

DECLARE 
  arrayvalues sys.odcivarchar2list;
BEGIN
  arrayvalues := sys.odcivarchar2list('Matt','Joanne','Robert');
  FOR x IN ( SELECT m.column_value m_value
               FROM table(arrayvalues) m )
  LOOP
    dbms_output.put_line (x.m_value||' is a good pal');
  END LOOP;
END;

Ich würde In-Memory-Array verwenden. Aber mit dem .COUNT Verbesserung vorgeschlagen von Uziberia:

DECLARE
  TYPE t_people IS TABLE OF varchar2(10) INDEX BY PLS_INTEGER;
  arrayvalues t_people;
BEGIN
  SELECT *
   BULK COLLECT INTO arrayvalues
   FROM (select 'Matt' m_value from dual union all
         select 'Joanne'       from dual union all
         select 'Robert'       from dual
    )
  ;
  --
  FOR i IN 1 .. arrayvalues.COUNT
  LOOP
    dbms_output.put_line(arrayvalues(i)||' is my friend');
  END LOOP;
END;

Eine andere Lösung wäre die Verwendung einer Hashmap wie bei @Jchomel hier .

NB:

Mit Oracle 12c können Sie sogar Arrays direkt abfragen !

11
Jika

Eine andere Lösung besteht darin, eine Oracle-Sammlung als Hashmap zu verwenden:

declare 
-- create a type for your "Array" - it can be of any kind, record might be useful
  type hash_map is table of varchar2(1000) index by varchar2(30);
  my_hmap hash_map ;
-- i will be your iterator: it must be of the index's type
  i varchar2(30);
begin
  my_hmap('a') := 'Apple';
  my_hmap('b') := 'box';
  my_hmap('c') := 'crow';
-- then how you use it:

  dbms_output.put_line (my_hmap('c')) ;

-- or to loop on every element - it's a "collection"
  i := my_hmap.FIRST;

  while (i is not null)  loop     
    dbms_output.put_line(my_hmap(i));      
    i := my_hmap.NEXT(i);
  end loop;

end;
11
J. Chomel