it-swarm.com.de

Was ist der beste Weg, um die Größe eines BitmapData-Objekts zu ändern?

Angenommen, ich habe ein BitmapData-Format von 600x600 und möchte es auf 100x100 verkleinern.

34
Iain

Das funktioniert:

var scale:Number = 1.0/6.0;
var matrix:Matrix = new Matrix();
matrix.scale(scale, scale);

var smallBMD:BitmapData = new BitmapData(bigBMD.width * scale, bigBMD.height * scale, true, 0x000000);
smallBMD.draw(bigBMD, matrix, null, null, null, true);

var bitmap:Bitmap = new Bitmap(smallBMD, PixelSnapping.NEVER, true);
68
Iain
public function drawScaled(obj:IBitmapDrawable, thumbWidth:Number, thumbHeight:Number):Bitmap {
    var m:Matrix = new Matrix();
    m.scale(WIDTH / obj.width, HEIGHT / obj.height);
    var bmp:BitmapData = new BitmapData(thumbWidth, thumbHeight, false);
    bmp.draw(obj, m);
    return new Bitmap(bmp);
}

IBitmapDrawable ist eine Schnittstelle für DisplayObject und BitmapData. 

von: http://www.nightdrops.com/2009/02/quick-reference-drawing-a-scaled-object-in-actionscript/

19
Carlo

Mit Glättung:

function BitmapScaled(source:IBitmapDrawable, thumbWidth:Number, thumbHeight:Number):BitmapData {
    var mat:Matrix = new Matrix();
    mat.scale(thumbWidth/source.width, thumbHeight/source.height);
    var bmpd_draw:BitmapData = new BitmapData(thumbWidth, thumbHeight, false);
    bmpd_draw.draw(source, mat, null, null, null, true);
    return bmpd_draw;
}

Die draw-Methode akzeptiert IBitmapDrawable , eine Schnittstelle für DisplayObject und BitmapData. 

10
sodah

Ohne den Code selbst zu schreiben. Ich würde an diese Methode herangehen, indem Sie ein neues BitmapData-Objekt der gewünschten Größe erstellen und anschließend die bitmap.draw-Methode verwenden, um das große Objekt in das kleine Objekt zu kopieren. Die bitmap.draw-Methode akzeptiert auch ein Matrixargument, das Sie beim Kopieren zum Skalieren verwenden können.

1
James Hay

Das Problem bei der Verwendung der Matrix-Skalierung besteht darin, dass keine Antialiasing- oder Glättungseffekte ausgeführt werden. Dies ist wahrscheinlich in Ordnung, wenn Sie sicher sind, dass Sie nur Downscaling-Vorgänge durchführen würden. Eine allgemeinere Methode würde jedoch die Image-Klasse verwenden, um die Größe zu ändern. In AS3 würde dies niemals zur Anzeigeliste hinzugefügt, es würde also nur "offscreen" verwendet. So etwas (mit Ihren Bitmap-Daten als "sourceBitmapData"):

var image:Image = new Image();
image.load(new Bitmap(sourceBitmapData, PixelSnapping.NEVER, true));

var scale:uint = 100/600; // this is from your example of 600x600 => 100x100
var scaledWidth:uint = sourceBitmapData.width * scale;
var scaledHeight:uint = sourceBitmapData.height * scale;

image.content.width = scaledWidth;
image.content.height = scaledHeight;

var scaledBitmapData:BitmapData = new BitmapData(scaledWidth, scaledHeight);
scaledBitmapData.draw(image.content); 

image = null;

Sie können dann "scaledBitmapData" anstelle von "sourceBitmapData" verwenden, um das auszuführen.

0
MicroAngelo

Hier ist eine Variation des obigen, die Unterstützung für Zoom, Stretch und Letterbox bietet. Es wird möglicherweise keine Clipunterstützung bereitgestellt. 

var newSizeBitmapData:BitmapData = resizeBitmapData(myBitmapData, newWidth, newHeight);


/**
 * Resize display object or bitmap data to a new size
 **/
public static function resizeBitmapData(bitmapDrawable:IBitmapDrawable, width:Number, height:Number, scaleMode:String="none", 
                                      smooth:Boolean = true, transparent:Boolean = true, fillColor:Number = 0x00000000):BitmapData {
    var sizedBitmapData:BitmapData;
    var matrix:Matrix;
    matrix = getSizeByScaleMode(width, height, Object(bitmapDrawable).width, Object(bitmapDrawable).height, scaleMode);
    sizedBitmapData = new BitmapData(width, height, transparent, fillColor);
    sizedBitmapData.draw(bitmapDrawable, matrix, null, null, null, smooth);

    return sizedBitmapData;
}

// Get correct scale. Inspired from code in Apache Flex (license Apache 2.0) 
public static function getSizeByScaleMode(maxWidth:int, maxHeight:int, 
                                          width:int, height:int, 
                                          scaleMode:String="letterbox",
                                          dpi:Number=NaN):Matrix {

    var aspectRatio:String = (maxWidth < maxHeight) ? "portrait" : "landscape";
    var orientation:String = aspectRatio;

    var matrix:Matrix = new Matrix();

    var scaleX:Number = 1;
    var scaleY:Number = 1;

    switch(scaleMode) {
        case "zoom":
            scaleX = Math.max( maxWidth / width, maxHeight / height);
            scaleY = scaleX;
            break;

        case "letterbox":
            scaleX = Math.min( maxWidth / width, maxHeight / height);
            scaleY = scaleX;
            break;

        case "stretch":
            scaleX = maxWidth / width;
            scaleY = maxHeight / height;
            break;
    }

    if (scaleX != 1 || scaleY != 0) {
        width *= scaleX;
        height *= scaleY;
        matrix.scale(scaleX, scaleY);
    }

    matrix.translate(-width / 2, -height / 2);

    matrix.translate(maxWidth / 2, maxHeight / 2);

    return matrix;
}
0
1.21 gigawatts