it-swarm.com.de

Zählen Sie verschiedene Werte in der Tabelle

Ich habe eine Google-Tabelle mit einer Spalte, die so aussieht:

City
----
London
Paris
London
Berlin
Rome
Paris

Ich möchte die Erscheinungsbilder jeder einzelnen Stadt zählen (daher benötige ich den Namen der Stadt und die Anzahl der Erscheinungsbilder).

City   | Count
-------+------
London |  2
Paris  |  2
Berlin |  1
Rome   |  1

Wie mache ich das?

66
Marius Bancila

Link zu Arbeitsbeispielen

Lösung 0

Dies kann mit Hilfe von Pivot-Tischen begleitet werden.

Pivot table Example - Count rows by value

Lösung 1

Verwenden Sie die Formel unique, um alle eindeutigen Werte abzurufen. Verwenden Sie dann countif, um die Anzahl der einzelnen Werte abzurufen. Sehen Sie sich den Arbeitsbeispiel-Link oben an, um genau zu sehen, wie dies implementiert wird.

Unique Values        Count
=UNIQUE(A3:A8)       =COUNTIF(A3:A8,B3)
                     =COUNTIF(A3:A8,B4)
                     ...

Lösung 2

Wenn Sie Ihre Daten als solche einrichten:

City    
----    
London   1
Paris    1
London   1
Berlin   1
Rome     1
Paris    1

Das Folgende führt dann zum gewünschten Ergebnis.

=sort(transpose(query(A3:B8,"Select sum(B) pivot (A)")),2,FALSE)

Ich bin sicher, dass es einen Weg gibt, die zweite Spalte loszuwerden, da alle Werte 1 sind. Meiner Meinung nach keine ideale Lösung.

über http://googledocsforlife.blogspot.com/2011/12/counting-unique-values-of-data-set.html

Andere möglicherweise hilfreiche Links

82
JSuar

=iferror(counta(unique(A1:A100))) zählt die Anzahl der eindeutigen Zellen von A1 bis A100

18
d-_-b

Sie können die Funktion query verwenden. Wenn sich Ihre Daten also in Spalte A befänden, in der die erste Zeile der Spaltentitel war ...

=query(A2:A,"select A, count(A) where A != '' group by A order by count(A) desc label A 'City'", 0)

ausbeuten

City    count 
London  2
Paris   2
Berlin  1
Rome    1

Link zu funktionierendem Google Sheet.

https://docs.google.com/spreadsheets/d/1N5xw8-YP2GEPYOaRkX8iRA6DoeRXI86OkfuYxwXUCbc/edit#gid=

10
Mike Latch

Nicht genau das, was der Benutzer gefragt hat, aber ein einfacher Weg, um nur eindeutige Werte zu zählen:

Google hat eine neue Funktion eingeführt, um eindeutige Werte in nur einem Schritt zu zählen, und Sie können diese als Eingabe für andere Formeln verwenden:

=COUNTUNIQUE(A1:B10)

3
Fabricio PH

Dies funktioniert, wenn Sie nur die Anzahl der eindeutigen Werte in z. den folgenden Bereich

=counta(unique(B4:B21))
1
Paul

Dies ähnelt Lösung 1 von @JSuar ...

Angenommen, Ihre ursprünglichen Stadtdaten sind ein benannter Bereich mit dem Namen dataCity. Geben Sie in einem neuen Blatt Folgendes ein:

    A                 | B
  ----------------------------------------------------------
1 | =UNIQUE(dataCity) | Count
2 |                   | =DCOUNTA(dataCity,"City",{"City";$A2})
3 |                   | [copy down the formula above]
4 |                   | ...
5 |                   | ...
0
dnlbrky