it-swarm.com.de

Excel - Array-Formel zum Überspringen leerer Zellen

Ich habe eine Matrixformel, um die Zelle auszufüllen, wenn sie Text enthält, aber ich möchte, dass die Zelle ignoriert wird, wenn sie leer ist und zur nächsten übergeht. Das Problem, das ich habe, ist, dass es dies nicht in der Reihenfolge tut, die ich zum Beispiel habe:

Reichweite ist

-A
-(BLANK CELL)
-(BLANK CELL)
-D
-E
-F
-(BLANK CELL)
-H
-(BLANK CELL)

Ergebnis aus der Formel

-A
-E
-F
-H

Es werden die Zellen übersprungen, die Buchstaben enthalten. Kann jemand helfen?

FORMEL:

{=IF(ISERROR(SMALL(IF(B4:$B$12<>"",ROW(B4:$B$12)),ROW(B4:$B$12)-3)),"",INDEX(B4:$B$12,MATCH(SMALL(IF(B4:$B$12<>"",ROW(B4:$B$12)),ROW(B4:$B$12)-3),IF(B4:$B$12<>"",ROW(B4:$B$12)),0)))}

6
PhoenixJay

Ich denke, das Problem ist, dass Sie den Bereich als B4:$B$12 haben, da es also keine $ -Zeichen um B4 gibt, ändert sich diese Referenz, wenn Sie die Formel in der Spalte nach unten ziehen ....... aber die Formel sieht etwas komplexer aus als Sie Ich würde eher eine bessere Alternative vorschlagen:

Welche Excel-Version verwenden Sie?

Probieren Sie diese Version in Excel 2007 oder höher aus

=IFERROR(INDEX(B$4:B$12,SMALL(IF(B$4:B$12<>"",ROW(B$4:B$12)-ROW(B$4)+1),ROWS(D$4:D4))),"")

Angenommen, Ihre erste Zelle ist D4 (ändern Sie ROWS(D$4:D4) so, dass sie Ihrer tatsächlichen Startzelle entspricht), und Sie ziehen die Formel in der Spalte nach unten

bestätigt mit CTRL+SHIFT+ENTER

In früheren Versionen, in denen die Funktion IFERROR nicht verfügbar ist, können Sie diese Version verwenden

=IF(ROWS(D$4:D4)>COUNTA(B$4:B$12),"",INDEX(B$4:B$12,SMALL(IF(B$4:B$12<>"",ROW(B$4:B$12)-ROW(B$4)+1),ROWS(D$4:D4))))

7
barry houdini

Es wurde eine einfachere und einfachere Methode gefunden. Grundsätzlich betrachtet Excel alle leeren Zellen ("") als gleich. Eine andere einfache Möglichkeit besteht darin, die Spalte mit den Daten auszuwählen und auf Duplicates entfernen unter der Registerkarte Daten zu klicken. Diese Option wird entfernt (überspringen) alle leeren leeren Zellen.

 Simple and easy way to remove blank cells from a column in Excel - by Francis Lacle

1
Francis Laclé